AS3 RadioButts Variable übergeben

[johanna52]

Hallo alle zusammen,

ich habe ein kl. Formular mit 2 Textfeldern und 2 Radiobutton (Komponenten) erstellt. Auf der nächsten Seite werden die Eingaben dann wieder ausgegeben, was mit den Textfeldern kein Problem ist. Aber die Variabeln Herr oder Frau von den beiden RadioButton wollen einfach nicht.

Der Code zeigt so im Moment keine Fehlermeldung. Er übergibt auch den trace-Inhalt. Bei der Ausgabe auf der 2. Seite erhalte ich "null". Jeder Versuch, das value Frau bzw. Herr aus den Komponentenparametern als Ausgabe zu bekommen, schlagen fehl. Der Gruppenname ist geschlecht.

Kann mir jemand weiterhelfen? Bin für jeden Tipp dankbar.

var senderName:String = name_txt.text;
var senderHobby:String = hobby_txt.text;
//var geschlecht:String = geschlecht.text;

weiter_btn.addEventListener(MouseEvent.CLICK,weiterbutt);

function weiterbutt(e:MouseEvent):void
{
	senderName=name_txt.text;
	senderHobby=hobby_txt.text;
if(herr_txt.selected==true) {
		trace("Herr wurde aktiviert");
		//geschlecht= herr_txt.text;
	} 
if(frau_txt.selected==true) {
	trace("Frau wurde aktiviert");
	//geschlecht= frau_txt.text;
	}
gotoAndStop("weiter");
}

stop();

 

[ad86]

AW: AS3 RadioButts Variable übergeben

Hi,

1.

var geschlecht:String = geschlecht.text;

Was soll das bitte? Du kannst doch aus der RadioButtonGroup (??) oder Textfeld "geschlecht" nicht einen String machen.

Änder das mal in:

var geschlecht[COLOR="Red"]Str[/COLOR]:String = geschlecht.text;

2. Wenn der Fehler immer noch nicht behoben ist. Sowie ich das gerade gelesen habe:

if (geschlecht.selection==null){
    //Fehler, nichts wurde ausgewaehlt
}
else{
    geschlechtString=geschlecht.selection.label;//"Herr" oder "Frau"
}

Die letzte Zeile hängt aber davon ab, wie Du Herr und Frau dem RadioButton
zugewiesen hast.

MFG ad86

 

[johanna52]

AW: AS3 RadioButts Variable übergeben

Hallo ad86,

also ein Textfeld geschlecht gibt es nicht - geschlecht ist der Gruppenname von den beiden RadioButton, welche ich in den Komponentenparametern (EigenschaftenPalette) eingegeben habe - und bei label und value steht Herr bzw. Frau --> Instanznamen ist herr_txt bzw. frau_txt -->

Ich habe nun

var geschlechtStr:String = geschlecht.text;

eingegeben.

Es kommt die Fehlermeldung: Eigenschaft geschlecht ist nicht definiert

auch die if-else bzw. meine if - Anweisungen bringen die Fehlermeldung (geschlecht nicht definiert) - habe mein geschlecht auch auf geschlechtStr geändert. Irgendwie steh ich auf dem Schlauch.

 

[ad86]

AW: AS3 RadioButts Variable übergeben

Hi,

kleines Beispiel von mir:

1. Version, wenn Du die zwei RadioBtn schon auf der Bühne hast (ist wohl der Fall)

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

weiter_mc.addEventListener(MouseEvent.CLICK, clickHandler);

function clickHandler(e:MouseEvent):void{
	var rbg:RadioButtonGroup=RadioButtonGroup.getGroup("geschlecht");
	if (rbg.selection){
		trace(rbg.selection.label);
		geschlechtStr=rbg.selection.label;
	}
	else{
		//Fehler
	}
}

Und nur AS3-Version

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioBtnGroup:RadioButtonGroup=new RadioButtonGroup("geschlecht");
var mann_rb:RadioButton = new RadioButton();
mann_rb.group = radioBtnGroup;
mann_rb.label = "Herr";
mann_rb.move(50, 50);
addChild(mann_rb);

var weib_rb:RadioButton = new RadioButton();
weib_rb.group = radioBtnGroup;
weib_rb.label = "Frau";
weib_rb.move(150, 50);
addChild(weib_rb);

weiter_mc.addEventListener(MouseEvent.CLICK, clickHandler);

function clickHandler(e:MouseEvent):void{
	if (radioBtnGroup.selection){
		trace(radioBtnGroup.selection.label);
		geschlechtStr=radioBtnGroup.selection.label;
	}
	else{
		//Fehler
	}
}

Anmerkung: Es muss ein Btn/MC namens "weiter_mc" vorhanden sein. Der Rest wird über AS3 gemacht.


EDit:
Schreibe (bitte) am Anfang nur

var geschlechtStr:String;

NICHT:

var geschlechtStr:String = geschlecht.text;

MFG ad86

 

[johanna52]

AW: AS3 RadioButts Variable übergeben

danke, wie immer genial. Funktioniert phantastisch.