Scrollshooter in Flash

[Schl4mp3]

Liebe Community,

ich bin gerade in Flash eingestiegen, nehme aber Programmiererfahrung und Basiswissen (Kollisionsabfragen) aus Delphi mit. Jetzt habe ich aber ein riesiges Problem, dass ich mich relativ schnell in Flash einarbeiten müsste und das würde ich gerne mit einem wirklich kleinen Spiel machen.

Zunächst zu dem Spiel:

Es soll so eine Art Shooter werden, bei dem man mit einem Objekt (Raumschiff oder Ähnliches) Gegner (Beispielsweise Aliens) abschießen (mit Kugeln, oder Laserstrahlen) muss.
Ich möchte, dass hierbei einfach eine Anzahl an Gegner festegelegt ist (3-6), die von rechts nach links über den Bildschirm fahren (Das habe ich jetzt auch erreicht) und wenn sie den linken Bildschirmrand erreicht haben sollen sie rechts wieder aus dem rechten Bildschirmrand her auftauchen.
Das Raumschiff wird mit der Maus bewegt (funktioniert auch) und mit einem Mausklick (da liegt der erste Hund begraben) soll ein Projektil (Kugel, Lasersschuss, ö.ä.) abgefeuert werden.

Kann mir jemand erklären, wie ich das mit dem Mausklick hinbekomme, sodass dann das Projektil von dem Raumschiff aus auf der x-Achse verschoben in die Richtung des rechten Bildschirmrrandes fliegt?
Dann bräuchte ich eine Kollisionsabfrage, welche ich bereits in Delphi gemacht habe, müsste also nur wissen, wie ich die Positionen der Objekte herausbekomme und miteinander Vergleiche (Delphi ist ja einfach mit Variablen, oder Objekt.Top / Left). Gibt es da etwas ähnliches?

Wäre über einige kleine Tipps, Hilfen sehr dankbar.

Ich verlange nicht, dass ihr für mich die Sache programmiert, möchte nur gerne eine Hilfe haben .
Wenn jemand eine Möglichkeit kennt, ein normales *.exe Programm in ein FlashMovie umzuwandeln (Programmiert in Delphi natürlich), so lasst es mich wissen

 

[Kerstin77]

AW: Scrollshooter in Flash

Hallo,

AS2 oder AS3?

Grüße,
Kerstin

 

[Kerstin77]

AW: Scrollshooter in Flash

Hey,

da ich irgendwie noch nicht so recht schlafen kann, hab ich hier mal ein kleines Beispiel zusammengebastelt (AS3):

var geschossen:Boolean;
var anzahl_ufos:uint = 5;
var treffer:uint;
var daneben:uint;

var spieler_mc:Spieler = new Spieler();
spieler_mc.x = 0;
spieler_mc.y = stage.stageHeight/2;
addChild(spieler_mc);

var kugel_mc:Kugel = new Kugel();
var ufo_mc:Ufo = new Ufo();

function reset_kugel():void {
    geschossen = false;
    kugel_mc.x = spieler_mc.width;
    kugel_mc.y = spieler_mc.y;
    addChild(kugel_mc);
}

function reset_ufo():void {
    ufo_mc.x = stage.stageWidth;
    ufo_mc.y = Math.floor(Math.random()*(stage.stageHeight-50))+25;
    addChild(ufo_mc);
}

reset_kugel();
reset_ufo();

function spielsteuerung(evt:Event):void {
    if (geschossen) {
        kugel_mc.x += 10;
        if (kugel_mc.x > stage.stageWidth) {
            reset_kugel();
        }
        if (kugel_mc.hitTestObject(ufo_mc)) {
            treffer++;
            if (treffer + daneben == anzahl_ufos) {
                spielende();
            } else {
                reset_kugel();
                reset_ufo();
            }
        }
    }
    ufo_mc.x -= 10;
    if (ufo_mc.x <= 50) {
        daneben++;
        if (treffer + daneben == anzahl_ufos) {
            spielende();
        } else {
            reset_ufo();
        }
    }
}

function spielerbewegung(evt:MouseEvent):void {
    spieler_mc.y = mouseY;
    if (!geschossen) {
        kugel_mc.y = mouseY;
    }
}

function schiessen(evt:MouseEvent):void {
    geschossen = true;
}

function spielende():void {
    stage.removeEventListener(Event.ENTER_FRAME, spielsteuerung);
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, spielerbewegung);
    stage.removeEventListener(MouseEvent.CLICK, schiessen);
    removeChild(ufo_mc);
    removeChild(spieler_mc);
    removeChild(kugel_mc);
    trace("Treffer: " + treffer);
    trace("Daneben: " + daneben);
}
    

stage.addEventListener(Event.ENTER_FRAME, spielsteuerung);
stage.addEventListener(MouseEvent.MOUSE_MOVE, spielerbewegung);
stage.addEventListener(MouseEvent.CLICK, schiessen);

Grüße,
Kerstin

 

[Schl4mp3]

AW: Scrollshooter in Flash

Hui, das ist viel code^^
ich werde mich mal da durch graben und eventuelle fragen posten, danke auf jeden fall schonmal
(Benutze Flash 8 Pro)

 

[Phosphoridos]

AW: Scrollshooter in Flash

Hei!

Ich weiß es nicht, weiß aber, dass es bei kongregate.com mittlerweile auch tutorials gibt.
vielleicht findet sich da ja was?

 

[FlashSoft]

AW: Scrollshooter in Flash

Wenn du nach Shooter Tutorials suchst, dann schau hier:





FlashSoft

 

[Kerstin77]

AW: Scrollshooter in Flash

Flash 8? Das hättest Du eher schreiben sollen, dann kannst Du mit dem obigen Code nichts anfangen.

Grüße,
Kerstin

 

[Schl4mp3]

AW: Scrollshooter in Flash

Ich danke euch allen, hab ein wenig gebastelt und mich dafür entschieden, erstmal bei Delphi und C++ zu bleiben.
Vielen dank für eure Mühen!