4 Videos gleichzeitig abspielen

[Sensey]

Hallo liebe Community,

ich bin Flash-Neuling und würde mich über eure Hilfe zur Erstellung meiner Belegaufgabe freuen.

Folgendes Szenario ist geplant:
> Ich möchte gerne mehrere Videosequenzen abspielen
> Jede Sequenz ist in 4 Varianten vorhanden (unterschiedliche Effekte) / also je Sequenz 4 Videofiles
> Mit einem oder mehreren Buttons soll es möglich sein zwischen diesen Files hin und her zu switchen
> Es soll also jeweils immer nur ein Video sichtbar sein

Fragen:
> Wie implementiere ich am besten die Files, dass sie synchron starten?
> Wie realisiert man am einfachsten die Ein- / Ausblendung der Videos?
> Löst man das mit visibilty=true bzw. visibility=false oder alpha=0 / alpha=1?

Ich freue mich über jede Antwort.
Vielen Dank im Vorraus.

 

[fairyofdarkness]

AW: 4 Videos gleichzeitig abspielen

suchst du das
http://www.youtube.com/watch?v=VxOf-VQxN4U
oder das

oder das?

hab es nicht ganz verstanden!

 

[Sensey]

AW: 4 Videos gleichzeitig abspielen

Also eigentlich ist von jedem Beispiel etwas dabei.

Ich versuche es mal genauer zu beschreiben.
Ich würde gerne einen interaktiven Film gestalten.
Ich habe 3 unterschiedliche Filmsequenzen.
Jede Filmsequenz existiert in 4 Varianten (unterschiedliche Filmeffekte).

> Der Film beginnt mit Sequenz 1 und Variante A
> über einen von 4 Buttons (A,B,C,D) möchte ich auf die jeweilige Varianten (B,C,D) der Sequenz "switchen"/ überblenden oder einfach wechseln können.
> Der Film soll beim Wechsel nicht unterbrochen werden und eben an der gleichen Stelle weiterspielen.

Wie ist sowas mit Flash machbar?
@fairyofdarkness Danke schon mal für dein Bemühen.

 

[ADcosmos]

AW: 4 Videos gleichzeitig abspielen

Hi,

1. Du solltest alle Videos im Format flv oder f4v haben.
2. Bei drei Szenen und je vier Videos hast Du also insgesamt 12 Videos
3. In die Bibliothek von Flash die FLVPlayback-Komponenete ziehen
4. Das Script nutzen (Ich hab nur drei Parts pro Video genutzt)

//In der Bibliothek sollte die FLVPlayback-Komponente sein.
import fl.video.VideoEvent;
import fl.video.VideoPlayer;

//Deine Pfade zu den Videos sollten im movArray gespeichert sein.
var movArray:Array= new Array("test1.f4v","test2.f4v","test3.f4v","test4.f4v","test5.f4v","test6.f4v","test7.f4v","test8.f4v","test9.f4v");
var playerArray:Array= new Array();
var movPerPart:int=3;//Anzahl der Videos pro Part, bei Dir 4
var loadedMov:int=0;//Nicht aendern
var partNumber:int=0;//Nicht aendern
var selectedPartIndex:int=0;//Nur aendern, wenn anderer StartIndex

//ERstellen der Btns
var mov1_btn:MovieClip=new MovieClip();
mov1_btn.name="mov0_btn";//Name sollte mit 0 beginnen.
mov1_btn.graphics.beginFill(0xff0000);
mov1_btn.graphics.drawRoundRect(0,0,100,40,10);
mov1_btn.graphics.endFill();
mov1_btn.visible=false;
mov1_btn.buttonMode=true;
mov1_btn.addEventListener(MouseEvent.CLICK, clickHandler);
var mov2_btn:MovieClip=new MovieClip();
mov2_btn.name="mov1_btn";
mov2_btn.graphics.beginFill(0x00ff00);
mov2_btn.graphics.drawRoundRect(0,0,100,40,10);
mov2_btn.graphics.endFill();
mov2_btn.visible=false;
mov2_btn.buttonMode=true;
mov2_btn.addEventListener(MouseEvent.CLICK, clickHandler);
var mov3_btn:MovieClip=new MovieClip();
mov3_btn.name="mov2_btn";
mov3_btn.graphics.beginFill(0x0000ff);
mov3_btn.graphics.drawRoundRect(0,0,100,40,10);
mov3_btn.graphics.endFill();
mov3_btn.visible=false;
mov3_btn.buttonMode=true;
mov3_btn.addEventListener(MouseEvent.CLICK, clickHandler);

//Videos laden und auf Buehne legen
for (var i:int=0; i<movArray.length; i++){
	var videoPlayer:VideoPlayer= new VideoPlayer(800,600);//Groesse jedes Videos
	videoPlayer.addEventListener(VideoEvent.READY, readyHandler);
	if (i%movPerPart==0){
		videoPlayer.addEventListener(Event.COMPLETE, completeHandler);
	}
	videoPlayer.autoRewind=true;
	videoPlayer.visible=false;
	stage.addChild(videoPlayer);
	videoPlayer.load(movArray[i]);
	playerArray.push(videoPlayer);
}

//Btns ueber Videos platzieren
mov1_btn.y=mov2_btn.y=mov3_btn.y=stage.stageHeight-mov1_btn.height-40;
mov1_btn.x=100;
mov2_btn.x=300;
mov3_btn.x=500;
stage.addChild(mov1_btn);
stage.addChild(mov2_btn);
stage.addChild(mov3_btn);


/*	Method is invoked, when the user clicks on one button
*/
function clickHandler(e:Event):void{
	var index:String=e.target.name.substring(3,e.target.name.indexOf("_"));
	selectedPartIndex=parseInt(index);
	for(var i:int=partNumber*movPerPart, j=0; i<partNumber*movPerPart+movPerPart;i++, j++){
		if (j==selectedPartIndex){
			playerArray[i].visible=true;
		}
		else{
			playerArray[i].visible=false;
		}
	}
}

/*	Method is invoked when one movie is loaded.
	
	After all movies are loaded, the first ones come visible
*/
function readyHandler(e:VideoEvent):void{
	loadedMov++;
	if (loadedMov==movArray.length){
		showPart();
		mov1_btn.visible=true;
		mov2_btn.visible=true;
		mov3_btn.visible=true;
	}	
}

/*	Method is invoked, when a movie is finished playing
*/
function completeHandler(e:Event):void{
	e.target.visible=false;
	partNumber++;
	if(partNumber<movArray.length/movPerPart){
		showPart();
	}
	else{
		mov1_btn.visible=false;
		mov2_btn.visible=false;
		mov3_btn.visible=false;
	}	
}

/*	Method shows the next part of the movie series and starts all movies within this series
*/
function showPart():void{
	for(var i:int=partNumber*movPerPart, j=0; i<partNumber*movPerPart+movPerPart;i++, j++){
		if (j==selectedPartIndex){
			playerArray[i].visible=true;
		}
		playerArray[i].play();
	}
}

MFG ADcosmos