Flash CS 6

[medien_adler]

Hi Leute, hat jemand eine Beispieldatei für einen Countdown-Zähler für einen Anfänger wie mich...?

Danke

 

[Wutknut]

AW: Flash CS 6

Vielleicht nützt dir das etwas: http://www.flashvortex.com/generators.php?generatorId=419

 

[ssandner]

AW: Flash CS 6

Hier mal ein Beispiel für einen Code der einen Countdown bis Sylvester liefert.
Auf der Bühne brauchst du nur ein dyn. Textfeld platzieren mit dem Instanznamen "time_txt"

//Erstellen eines Objektes mit dem Enddatum
var endDate:Date = new Date(2012,11,31,23); //Enddatum: 31.12.2012 Achtung beim Monat: Januar ist 0!!
//Einen Timer erstellen mit einer Laufzeit von 1000 mc  0 1 sec

var countdownTimer:Timer = new Timer(1000);
//Einen EventListener an den Timer hängen
countdownTimer.addEventListener(TimerEvent.TIMER, updateTime);
//Timer starten
countdownTimer.start();
//Brerechnung der Differenz aus aktuellem Datum/ Uhrzeit und Enddatum
function updateTime(e:TimerEvent):void
{
	//aktuelles Datum/ Uhrzeit
	var now:Date = new Date();
	var timeLeft:Number = endDate.getTime() - now.getTime();
	//Umrechnung in Sekunden, Minuten , Stunden und Tagen
	var seconds:Number = Math.floor(timeLeft / 1000);
	var minutes:Number = Math.floor(seconds / 60);
	var hours:Number = Math.floor(minutes / 60);
	var days:Number = Math.floor(hours / 24);
	
	//Aufrunden um Rechenfehler zu vermeiden
	seconds %= 60;
	minutes %= 60;
	hours %= 24;
	
	//Zeitwerte in String umwandeln 
	
	var sec:String = seconds.toString();
	var min:String = minutes.toString();
	var hrs:String = hours.toString();
	var d:String = days.toString();
	
	//Einstellige Zahlen auf zweistellige setzen
	if (sec.length < 2) {
		sec = "0" + sec;
	}
	
	if (min.length < 2) {
		min = "0" + min;
	}
	
	if (hrs.length < 2) {
		hrs = "0" + hrs;
	}
	
	//String zusammensetzen
	var time:String = d + ":" + hrs + ":" + min + ":" + sec;
	//dynamisches Textfeld mit String befüllen
	time_txt.text = time;
}