Error #1034

[D0gProjects]

Hallo liebes Forum und frohe Weihnachten!!

Hab folgendes Problem: Ich versuche einen Movieclip per Actionscript so zu bewgen, dass er sinusartig vom rechten Rand der Bühne zum linken Rand der Bühne "schwingt". Also hab ich mal mein Figürchen gezeichnet und lasse es als "BadGuy1" exportieren.

In der Main hab ich folgenden Code:

var b1:Sprite = new BadGuy1();
b1.x = 280;
b1.y = 100;
stage.addChild(b1);

ausserdem habe ich eine as-datei mit folgendem Code angelegt:

package
{
	import flash.events.Event;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	
	public class BadGuy1 extends Sprite 
	{
		private var core:Object;
		private var speed:int = 10;
		private var framecount:int = 0;
		
		public function BadGuy1()
		{
			addEventListener(Event.ADDED_TO_STAGE,onAdd);
		}
		
		private function onAdd (e:Event)
		{
			core = MovieClip (root);
			
			addEventListener(Event.ENTER_FRAME,loop);
		}
		
		private function loop (e:Event)
		{
			framecount++;
			speed = Math.sin(framecount*Math.PI)*280;
			x += speed;
		
		}
	}
}

Falls ich versuche, das Programm zu testen, erscheint der Movieclip ganz normal auf der Stage, bewegt sich jedoch nicht. Ausserdem bekomme ich folgenden Fehlercode:

TypeError: Error #1034: Typumwandlung fehlgeschlagen: flash.display::Stage@41ce1ba1 kann nicht in flash.display.MovieClip umgewandelt werden.
	at BadGuy1/onAdd()
	at flash.display::DisplayObjectContainer/addChild()
	at flash.display::Stage/addChild()
	at JumpAndRun_fla::MainTimeline/init()
	at JumpAndRun_fla::MainTimeline/frame10()

Danke für eure Hilfe!!!

 

[Kerstin77]

AW: Error #1034

Also wenn dann höchstes so:

core = this.parent;

Aber wozu soll das gut sein?

Grüße,
Kerstin

 

[D0gProjects]

AW: Error #1034

Hallo Kerstin!!

Danke für deine Antwort, die Fehlermeldung scheint weg zu sein, aber der Movieclip bewegt sich leider immer noch nicht hin und her...

 

[Kerstin77]

AW: Error #1034

Hi,

package {
    
    import flash.events.Event;
    import flash.display.MovieClip;
    import flash.display.Sprite;
    
    public class BadGuy1 extends Sprite {
        
        private var speed:int = 5;
        private var winkel:Number;
        private var ypos:int;
        
        public function BadGuy1() {
            addEventListener(Event.ADDED_TO_STAGE,onAdd);
        }
        
        private function onAdd (e:Event) {
            ypos = this.y;
            winkel = 0;
            addEventListener(Event.ENTER_FRAME,loop);
        }
        
        private function loop (e:Event) {
            winkel += speed;
            this.x += speed;
            this.y = ypos + Math.sin((winkel/180) * Math.PI) * 100;
        }
    }
}

Grüße,
Kerstin

 

[D0gProjects]

AW: Error #1034

Danke Kerstin, warst eine große Hilfe!
Habs jetzt geschafft.